;;;============================================
;;;Written By Michael Puckett.
;;;Список элементов символьных таблиц АвтоКАДа
;;; - s- имя таблицы
;;;Пример - список всех слоев - (setq all_layers (tablelist "LAYER"))
;;;(setq all_layers (tablelist "LAYER"))
;;;
;;;AutoLisp should return something like this :
;;;Start Coding Here
(defun tablelist (s / d r)
  (while (setq d (tblnext s (null d)))
    (setq r (cons (cdr (assoc 2 d)) r))
  )                ;while
)                ;defun

;Список блоков
(acad_strlsort(tablelist "BLOCK"))
;Список солев без слоев вн. ссылок
(acad_strlsort(vl-remove-if-not 'snvalid (tablelist "layer")))
;Список типов линий без типов линий вн. ссылок
(acad_strlsort(vl-remove-if-not 'snvalid (tablelist "LTYPE")))

(acad_strlsort(vl-remove-if '(lambda(x)(=(substr x 1 2)"*U"))(tablelist "BLOCK")))

(defun dynblockon (name on / adoc)
                 ;|
*     Включает или выключает видимость дин.блоков.
*    Параметры вызова:
    name    эффективное имя блока. nil -> обрабатывать все
    on    включать (t) или выключать (nil) видимость
|;
  (vl-load-com)
  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    );_ end of vla-startundomark
  (if (not name)
    (setq name "*")
    );_ end of if
  (vlax-for blk_def (vla-get-blocks adoc)
    (vlax-for ent blk_def
      (if (and (vlax-property-available-p ent 'isdynamicblock)
               (vlax-property-available-p ent 'effectivename)
               (equal (vla-get-isdynamicblock ent) :vlax-true)
               (wcmatch (strcase (vla-get-effectivename ent)) (strcase name))
               );_ end of and
        (vla-put-visible
          ent
          (if on
            :vlax-true
            :vlax-false
            );_ end of if
          );_ end of vla-put-visible
        );_ end of if
      );_ end of vlax-for
    );_ end of vlax-for
  (vla-regen adoc acallviewports)
  (vla-endundomark adoc)
  (princ)
  );_ end of defun

(defun dynblockon2 (name on / adoc)
                  ;|
*     Включает или выключает видимость дин.блоков.
*    Параметры вызова:
    name    указатель на вхождение блока. nil -> обрабатывать все
    on    включать (t) или выключать (nil) видимость
*    Примеры вызова:
(dynblockon2 nil t)    ; показать все дин.блоки
(dynblockon2 (car(entsel)) nil); скрыть блоки, аналогичные указанному
(dynblockon2 (car(entsel)) t); показать блоки, аналогичные указанному
|;
  (vl-load-com)
  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    );_ end of vla-startundomark
  (setq name
         (cond
           ((= (type name) 'ename) (cdr (assoc 2 (entget name))))
           ((= (type name) 'str) name)
           ((= (type name) 'vla-object) (vla-get-name name))
           (t nil)
           );_ end of cond
        );_ end of setq
  (vlax-for blk_def (vla-get-blocks adoc)
    (vlax-for ent blk_def
      (if (and (vlax-property-available-p ent 'isdynamicblock)
               (vlax-property-available-p ent 'effectivename)
               (equal (vla-get-isdynamicblock ent) :vlax-true)
               (if name
                 (equal (vla-get-name ent) name)
                 t
                 );_ end of if
               );_ end of and
        (vla-put-visible
          ent
          (if on
            :vlax-true
            :vlax-false
            );_ end of if
          );_ end of vla-put-visible
        );_ end of if
      );_ end of vlax-for
    );_ end of vlax-for
  (vla-regen adoc acallviewports)
  (vla-endundomark adoc)
  (princ)
  );_ end of defun

(vla-update (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) (vla-get-effectivename (car (entsel "\nтолько что редактировавшийся блок : ")))))

(defun test (/ adoc attr_number attr_pos _kpblc-conv-vla-to-list)

  (defun _kpblc-conv-vla-to-list (value / res)
                            ;|
*    Преобразовывает vlax-variant или vlax-safearray в список.
|;
    (cond
      ((= (type value) 'variant)
       (_kpblc-conv-vla-to-list (vlax-variant-value value))
       )
      ((= (type value) 'safearray)
       (if (>= (vlax-safearray-get-u-bound value 1) 0)
         (vlax-safearray->list value)
         );_ end of if
       )
      (t value)
      );_ end of cond
    );_ end of defun

  (vl-load-com)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (if
    (and
      (not
        (vl-catch-all-error-p
          (vl-catch-all-apply
            '(lambda ()
               (setq attr_number (car (nentsel "\nАтрибут номера <Отмена> : ")))
               );_ end of lambda
            );_ end of vl-catch-all-apply
          );_ end of vl-catch-all-error-p
        );_ end of not
      attr_number
      (setq attr_number (vlax-ename->vla-object attr_number))
      (wcmatch (strcase (vla-get-objectname attr_number)) "*ATTR*")
      (not
        (vl-catch-all-error-p
          (vl-catch-all-apply
            '(lambda ()
               (setq attr_pos (car (nentsel "\nАтрибут позиции <Отмена> : ")))
               );_ end of lambda
            );_ end of vl-catch-all-apply
          );_ end of vl-catch-all-error-p
        );_ end of not
      attr_pos
      (setq attr_pos (vlax-ename->vla-object attr_pos))
      (wcmatch (strcase (vla-get-objectname attr_pos)) "*ATTR*")
      (not (equal attr_pos attr_number))
      (/= (strcase (vla-get-tagstring attr_number))
          (strcase (vla-get-tagstring attr_pos))
          );_ end of /=
      (equal (vla-objectidtoobject adoc (vla-get-ownerid attr_pos))
             (vla-objectidtoobject adoc (vla-get-ownerid attr_number))
             );_ end of equal
      );_ end of and
     (progn
       (foreach item
                (vl-remove-if-not
                  '(lambda (x / lst)
                     (setq lst (_kpblc-conv-vla-to-list (vla-getattributes x)))
                     (and (member (strcase (vla-get-tagstring attr_number))
                                  lst
                                  );_ end of member
                          (member (strcase (vla-get-tagstring attr_pos))
                                  lst
                                  );_ end of member
                          );_ end of and
                     );_ end of lambda
                  (mapcar
                    'vlax-ename->vla-object
                    (vl-remove-if
                      'listp
                      (mapcar 'cadr (ssnamex (ssget '((0 . "INSERT") (66 . 1)))))
                      );_ end of vl-remove-if
                    );_ end of mapcar
                  );_ end of vl-remove-if-not
    ;| Ну а здесь уже проставление чего надо и куда надо - сам, батенька, сам :)|;
        );_ end of foreach
       );_ end of progn
     );_ end of if
  );_ end of defun